class website::mysql (
  $mysqluser,
  $mysqlpassword,
  $mysqlsuffix    = '',
  $phpsuffix      = '',
  $phpmysqlsuffix = '',
  $mysqlprefix    = 'mysql')
  {
  class { 'mysql::client':
    package_name    => "${mysqlprefix}${mysqlsuffix}",
    bindings_enable => false, #Deal with bindings manually
  }
  class { 'mysql::bindings':
    php_enable       => true,
    php_package_name => "php${phpsuffix}-mysql${phpmysqlsuffix}",
  }
  class { 'mysql::server':
    package_name => "${mysqlprefix}${mysqlsuffix}-server",
    override_options => {
      'mysqld' => {
        'query_cache_size' => '64M',
        'join_buffer_size' => '524288', #512K
        'tmp_table_size'   => '64M',
        'max_heap_table_size' => '64M',
        'table_open_cache' => '64',
        'log-queries-not-using-indexes' => '1',
        # Set a sensible default character set
        'character-set-server' => 'utf8',
        'collation-server' => 'utf8_general_ci',
        # Settings for best MySQL 4-byte Unicode support
        'innodb_large_prefix' => 'true',
        'innodb_file_format' => 'barracuda',
        'innodb_file_per_table' => '1',
      }
    },
  }
  $username = strip($mysqluser)
  $password = strip($mysqlpassword)
  $configured_marker = "/etc/.${mysqlprefix}.is-configured"
  exec { 'Rename root MySQL user for security':
    command  => "mysql -uroot -e 'UPDATE mysql.user SET User = \"$username\", Password = PASSWORD(\"$password\") WHERE User = \"root\"; DELETE FROM mysql.user WHERE User = \"\"; FLUSH PRIVILEGES;' && touch $configured_marker",
    provider => shell,
    creates  => $configured_marker,
    require  => Class['mysql::server'],
  }
}